かんがるーさんの日記

最近自分が興味をもったものを調べた時の手順等を書いています。今は Spring Boot をいじっています。

Spring Boot 2.2.x の Web アプリを 2.3.x へバージョンアップする ( その３ )( Spring Boot を 2.2.9 → 2.3.2 へバージョンアップする )

概要

記事一覧はこちらです。

Spring Boot 2.2.x の Web アプリを 2.3.x へバージョンアップする ( その２ )( Spring Boot を 2.2.2 → 2.2.9 へ、Gradle を 6.0.1 → 6.5.1 へバージョンアップする ) の続きです。

  • 今回の手順で確認できるのは以下の内容です。
    • Spring Boot を 2.2.9 → 2.3.2 へバージョンアップします。

参照したサイト・書籍

目次

  1. Spring Initializr で 2.3.2 のプロジェクトを作成する
  2. build.gradle を変更する
  3. build タスク実行時に出るエラーを修正する

手順

Spring Initializr で 2.3.2 のプロジェクトを作成する

Spring Initializr で 2.3.2 のプロジェクトを作成して、生成された build.gradle を見て反映した方が良い点があるか確認します。

f:id:ksby:20200809110940p:plain f:id:ksby:20200809111033p:plain f:id:ksby:20200809111134p:plain f:id:ksby:20200809111217p:plain f:id:ksby:20200809111258p:plain f:id:ksby:20200809111349p:plain f:id:ksby:20200809111529p:plain ※リストの一番下の「PostgreSQL Driver」もチェックします。 f:id:ksby:20200809111642p:plain f:id:ksby:20200809111729p:plain f:id:ksby:20200809111838p:plain f:id:ksby:20200809111951p:plain

以下の build.gradle が作成されました。

plugins {
    id 'org.springframework.boot' version '2.3.2.RELEASE'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'java'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.springframework.boot:spring-boot-starter-freemarker'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.session:spring-session-data-redis'
    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'org.postgresql:postgresql'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
    testImplementation 'org.springframework.security:spring-security-test'
}

test {
    useJUnitPlatform()
}

以下の点を build.gradle に反映します。

  • configurations block から以下の２行を削除します。
    • developmentOnly
    • runtimeClasspath.extendsFrom developmentOnly

build.gradle を変更する

buildscript {
    ext {
        group "ksbysample"
        version "2.3.2-RELEASE"
    }
    repositories {
        mavenCentral()
        maven { url "https://repo.spring.io/release/" }
        gradlePluginPortal()
    }
}

plugins {
    id "java"
    id "eclipse"
    id "idea"
    id "org.springframework.boot" version "2.3.2.RELEASE"
    id "io.spring.dependency-management" version "1.0.9.RELEASE"
    id "groovy"
    id "checkstyle"
//    id "com.github.spotbugs" version "3.0.0"
    id "pmd"
    id "net.ltgt.errorprone" version "1.1.1"
    id "com.gorylenko.gradle-git-properties" version "2.2.3"
}

..........

configurations {
    compileOnly.extendsFrom annotationProcessor

    // annotationProcessor と testAnnotationProcessor、compileOnly と testCompileOnly を併記不要にする
    testAnnotationProcessor.extendsFrom annotationProcessor
    testImplementation.extendsFrom compileOnly

    // for Doma 2
    domaGenRuntime

    // for SpotBugs
    spotbugsStylesheets { transitive = false }
}

..........

dependencyManagement {
    imports {
        // mavenBom は以下の URL のものを使用する
        // https://repo.spring.io/release/org/springframework/boot/spring-boot-starter-parent/2.2.9.RELEASE/
        // bomProperty に指定可能な property は以下の URL の BOM に記述がある
        // https://repo.spring.io/release/org/springframework/boot/spring-boot-dependencies/2.2.9.RELEASE/spring-boot-dependencies-2.2.9.RELEASE.pom
        mavenBom(org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES) {
            // Spring Boot の BOM に定義されているバージョンから変更する場合には、ここに以下のように記述する
            // bomProperty "thymeleaf.version", "3.0.9.RELEASE"
            bomProperty "groovy.version", "2.5.12"
        }
        mavenBom("org.junit:junit-bom:5.6.2")
    }
}

dependencies {
    def jdbcDriver = "org.postgresql:postgresql:42.2.14"
    def spockVersion = "1.3-groovy-2.5"
    def domaVersion = "2.26.0"
    def lombokVersion = "1.18.12"
    def errorproneVersion = "2.3.4"
    def powermockVersion = "2.0.7"
    def spotbugsVersion = "4.0.0-beta4"

    // dependency-management-plugin によりバージョン番号が自動で設定されるもの
    // Appendix F. Dependency versions ( https://docs.spring.io/spring-boot/docs/current/reference/html/appendix-dependency-versions.html ) 参照
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-thymeleaf")
    implementation("org.thymeleaf.extras:thymeleaf-extras-springsecurity5")
    implementation("org.springframework.boot:spring-boot-starter-data-jpa")
    implementation("org.springframework.boot:spring-boot-starter-freemarker")
    implementation("org.springframework.boot:spring-boot-starter-mail")
    implementation("org.springframework.boot:spring-boot-starter-security")
    implementation("org.springframework.boot:spring-boot-starter-data-redis")
    implementation("org.springframework.boot:spring-boot-starter-amqp")
    implementation("org.springframework.boot:spring-boot-starter-actuator")
    developmentOnly("org.springframework.boot:spring-boot-devtools")
    compileOnly("org.springframework.boot:spring-boot-configuration-processor")
    implementation("org.springframework.session:spring-session-data-redis")
    implementation("org.springframework.retry:spring-retry")
    implementation("com.fasterxml.jackson.dataformat:jackson-dataformat-xml")
    implementation("org.apache.commons:commons-lang3")
    implementation("org.codehaus.janino:janino")
    implementation("io.micrometer:micrometer-registry-prometheus")
    testImplementation("org.springframework.boot:spring-boot-starter-test") {
        exclude group: "org.junit.vintage", module: "junit-vintage-engine"
    }
    testImplementation("org.springframework.security:spring-security-test")
    testImplementation("org.yaml:snakeyaml")

    // dependency-management-plugin によりバージョン番号が自動で設定されないもの、あるいは最新バージョンを指定したいもの
    runtimeOnly("${jdbcDriver}")
    implementation("com.integralblue:log4jdbc-spring-boot-starter:2.0.0")
    implementation("org.simpleframework:simple-xml:2.7.1")
    implementation("com.univocity:univocity-parsers:2.8.4")
    implementation("com.google.guava:guava:29.0-jre")
    implementation("org.flywaydb:flyway-core:6.5.3")
    testImplementation("org.dbunit:dbunit:2.7.0") {
        exclude group: "postgresql", module: "postgresql"
    }
    testImplementation("com.icegreen:greenmail:1.5.14")
    testImplementation("org.assertj:assertj-core:3.16.1")
    testImplementation("com.jayway.jsonpath:json-path:2.4.0")
    testImplementation("org.jsoup:jsoup:1.13.1")
    testImplementation("cglib:cglib-nodep:3.3.0")
    testImplementation("org.spockframework:spock-core:${spockVersion}")
    testImplementation("org.spockframework:spock-spring:${spockVersion}")

    // for lombok
    // testAnnotationProcessor、testCompileOnly を併記しなくてよいよう configurations で設定している
    annotationProcessor("org.projectlombok:lombok:${lombokVersion}")
    compileOnly("org.projectlombok:lombok:${lombokVersion}")

    // for Doma
    annotationProcessor("org.seasar.doma:doma:${domaVersion}")
    implementation("org.seasar.doma:doma:${domaVersion}")
    domaGenRuntime("org.seasar.doma:doma-gen:${domaVersion}")
    domaGenRuntime("${jdbcDriver}")

    // for JUnit 5
    // junit-jupiter で junit-jupiter-api, junit-jupiter-params, junit-jupiter-engine の３つが依存関係に追加される
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")

    // for Error Prone ( http://errorprone.info/ )
    errorprone("com.google.errorprone:error_prone_core:${errorproneVersion}")
    compileOnly("com.google.errorprone:error_prone_annotations:${errorproneVersion}")

    // PowerMock
    testImplementation("org.powermock:powermock-module-junit4:${powermockVersion}")
    testImplementation("org.powermock:powermock-api-mockito2:${powermockVersion}")

    // for SpotBugs
//    compileOnly("com.github.spotbugs:spotbugs:${spotbugsVersion}") {
//        exclude group: "pull-parser", module: "pull-parser"
//    }
//    compileOnly("net.jcip:jcip-annotations:1.0")
    compileOnly("com.github.spotbugs:spotbugs-annotations:${spotbugsVersion}")
//    testImplementation("com.google.code.findbugs:jsr305:3.0.2")
//    spotbugsStylesheets("com.github.spotbugs:spotbugs:${spotbugsVersion}")
//    spotbugsPlugins("com.h3xstream.findsecbugs:findsecbugs-plugin:1.10.1")
}

..........

Spring Boot 2.3.2 へのバージョンアップとして以下の点を変更します。

  • buildscript block の以下の点を変更します。
    • version "2.2.9-RELEASE" → version "2.3.2-RELEASE"
  • plugins block の以下の点を変更します。
    • id "org.springframework.boot" version "2.2.9.RELEASE" → id "org.springframework.boot" version "2.3.2.RELEASE"
  • configurations block から以下の２行を削除します。
    • developmentOnly
    • runtimeClasspath.extendsFrom developmentOnly

各種ライブラリのバージョンアップとして以下の点を変更します。

  • plugins block の以下の点を変更します。
    • id "com.gorylenko.gradle-git-properties" version "2.2.0" → id "com.gorylenko.gradle-git-properties" version "2.2.3"
  • dependencyManagement block の以下の点を変更します。
    • mavenBom("org.junit:junit-bom:5.5.2") → mavenBom("org.junit:junit-bom:5.6.2")
  • dependencies block の以下の点を変更します。
    • def jdbcDriver = "org.postgresql:postgresql:42.2.9" → def jdbcDriver = "org.postgresql:postgresql:42.2.14"
    • def lombokVersion = "1.18.10" → def lombokVersion = "1.18.12"
    • def powermockVersion = "2.0.4" → def powermockVersion = "2.0.7"
    • implementation("com.google.guava:guava:28.1-jre") → implementation("com.google.guava:guava:29.0-jre")
    • implementation("org.flywaydb:flyway-core:6.1.3") → implementation("org.flywaydb:flyway-core:6.5.3")
    • testImplementation("org.dbunit:dbunit:2.6.0") → testImplementation("org.dbunit:dbunit:2.7.0")
    • testImplementation("com.icegreen:greenmail:1.5.11") → testImplementation("com.icegreen:greenmail:1.5.14")
    • testImplementation("org.assertj:assertj-core:3.14.0") → testImplementation("org.assertj:assertj-core:3.16.1")
    • testImplementation("org.jsoup:jsoup:1.12.1") → testImplementation("org.jsoup:jsoup:1.13.1")
    • Doma は domaGen タスクを変更する必要があるので後でバージョンアップします。

build タスク実行時に出るエラーを修正する

clean タスク実行 → Rebuild Project 実行。。。でエラーが出ました。パッケージjavax.validationは存在しません のエラーメッセージが出力されています。

f:id:ksby:20200809115730p:plain

Spring Boot 2.3 Release Notes の Validation Starter no longer included in web starters の記述に従い implementation("org.springframework.boot:spring-boot-starter-validation") を追加します。

dependencies {
    ..........
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-validation")

再度 Rebuild Project 実行を実行すると、今度は以下の警告が出ます。

f:id:ksby:20200809121807p:plain

１つ目は org.springframework.boot.web.servlet.error.ErrorControllerのgetErrorPath()は推奨されません で、ksbysample.webapp.lending.web.WebappErrorController クラスで getErrorPath メソッドを override していたのですが、

f:id:ksby:20200809122121p:plain

org.springframework.boot.web.servlet.error.ErrorController#getErrorPath メソッドを見ると Deprecated になっていました。エラーページの path は設定ファイルの server.error.path で設定することになったようです。

f:id:ksby:20200809125741p:plain

Spring Boot の Common Application properties のページを見ると server.error.path のデフォルト値は /error で ksbysample.webapp.lending.web.WebappErrorController#getErrorPath メソッドが返す値と同じですので、override している ksbysample.webapp.lending.web.WebappErrorController#getErrorPath メソッドに @SuppressWarnings("deprecation") を付与して警告が出ないようにします。

    @SuppressWarnings("deprecation")
    @Override
    public String getErrorPath() {
        return "/error";
    }

２つ目は org.junit.Assertの<T>assertThat(java.lang.String,T,org.hamcrest.Matcher<? super T>)は推奨されません で、これは JUnit 4 の assertThat メソッドを呼び出していたことが原因でした。AssertJ の assertThat に変更します。

再度 clean タスク実行 → Rebuild Project 実行 → build タスクを実行すると無事 "BUILD SUCCESSFUL" のメッセージが出力されました。

f:id:ksby:20200809130437p:plain

履歴

2020/08/09
初版発行。